add ikea lack stuff

ikea-lack/lack-simple-bracket.scad

@@ -0,0 +1,66 @@
+lack_foot_width = 50;
+lack_foot_height = 100;
+lack_foot_dist = 5;
+
+bracket_height = 70;
+bracket_width = 40;
+bracket_wall = 10;
+
+screw_head_length = 4.5;
+screw_head_dia_max = 8.0;
+screw_head_dia_min = 3.2;
+screw_body_dia = 2.4;
+screw_body_length = 25;
+
+$fn = 20;
+
+module screw() {
+    cylinder(d1 = screw_body_dia, d2 = screw_head_dia_min, h = screw_body_length + 0.1);
+    translate([0, 0, screw_body_length])
+    cylinder(d1 = screw_head_dia_min, d2 = screw_head_dia_max, h = screw_head_length);
+}
+
+module screw_block() {
+    translate([bracket_width / 3, screw_body_length + screw_head_length - bracket_wall - 0.1, 10])
+    rotate([90, 0, 0])
+    screw();
+    
+    translate([bracket_width * 2 / 3, screw_body_length + screw_head_length - bracket_wall - 0.1, 20])
+    rotate([90, 0, 0])
+    screw();
+}
+
+module bracket_body() {
+    translate([-bracket_wall, -bracket_wall, 0])
+    cube([bracket_width + bracket_wall, bracket_wall, bracket_height]);
+    
+    translate([-bracket_wall, 0, 0])
+    cube([bracket_wall, bracket_width, bracket_height]);
+}
+
+module bracket() {
+    difference() {
+        bracket_body();
+        
+        screw_block();
+        translate([0, 0, bracket_height / 2 + lack_foot_dist])
+        screw_block();
+        
+        translate([0, bracket_width, 0])
+        rotate([0, 0, -90])
+        screw_block();
+        
+        translate([0, bracket_width, bracket_height / 2 + lack_foot_dist])
+        rotate([0, 0, -90])
+        screw_block();
+    }
+}
+
+// feet visualization
+%translate([0, 0, -lack_foot_height])
+cube([lack_foot_width, lack_foot_width, lack_foot_height]);
+translate([0, 0, lack_foot_dist])
+%cube([lack_foot_width, lack_foot_width, lack_foot_height]);
+
+translate([0, 0, (lack_foot_dist - bracket_height) / 2])
+bracket();

ikea-lack/pipe_holder.scad

@@ -0,0 +1,91 @@
+tube = 16.5;
+wall = 6;
+depth = 12;
+mount = 1;
+wall_off = 3;
+tab = 11;
+hole = 4.1;
+
+head_min = hole;
+head_max = 7.9;
+head_height = 2.5;
+
+fix_height = 9;
+fix_wall = 4;
+fix_dia = 40;
+fix_hole = 2.8;
+
+double = true;
+
+$fn = 42;
+
+module fix() {
+    difference() {
+        cylinder(d = fix_dia, h = fix_height);
+        
+        translate([0, 0, -1])
+        cylinder(d = tube, h = fix_height + 2);
+            
+        translate([0, -1, fix_height / 2])
+        rotate([90, 0, 0])
+        cylinder(d = fix_hole, h = fix_dia / 2);
+            
+        translate([1, 0, fix_height / 2])
+        rotate([0, 90, 0])
+        cylinder(d = fix_hole, h = fix_dia / 2);
+    }
+}
+
+module tab() {
+    difference() {
+        cube([wall + wall_off, tab, depth]);
+        
+        translate([-1, tab / 2, depth / 2])
+        rotate([0, 90, 0]) {
+            cylinder(d = hole, h = wall + wall_off + 2);
+            
+            translate([0, 0, wall + wall_off + 1 - head_height])
+            cylinder(d1 = head_min, d2 = head_max, h = head_height + 0.01);
+        }
+    }
+}
+
+module main_part() {
+    hull() {
+        cylinder(d = tube + (2 * wall), h = depth);
+        
+        translate([-tube / 2 - wall_off, tube / 2 + wall, 0])
+        cube([wall + wall_off, mount, depth]);
+        
+        translate([-tube / 2 - wall_off, -tube / 2 - wall - mount, 0])
+        cube([wall + wall_off, mount, depth]);
+    }
+    
+    translate([-tube / 2 - wall_off, tube / 2 + wall + mount, 0])
+    tab();
+    
+    translate([-tube / 2 - wall_off, -tube / 2 - wall - mount - tab, 0])
+    tab();
+}
+
+module whole() {
+    difference() {
+        main_part();
+        
+        translate([0, 0, -1])
+        cylinder(d = tube, h = depth + 2);
+        
+        translate([-100 - tube / 2 - wall_off, -50, -50])
+        cube([100, 100, 100]);
+    }
+}
+
+translate([fix_dia + 10, 0, 0])
+fix();
+
+whole();
+
+if (double) {
+    translate([0, 0, depth])
+    whole();
+}