add stuff

clipper_mount/clipper.scad

@@ -0,0 +1,24 @@
+clipper_dia = 20;
+clipper_height = 5;
+
+clipper_dist = 10;
+clipper_floor = 2;
+
+count_x = 2;
+count_y = 1;
+
+module clipper() {
+    cylinder(d = clipper_dia, h = clipper_height + 1);
+}
+
+difference() {
+    cube([count_x * (clipper_dia + clipper_dist), count_y * (clipper_dia + clipper_dist), clipper_floor + clipper_height]);
+
+    for (x = [0 : count_x - 1]) {
+        for (y = [0 : count_y - 1]) {
+            translate([x * (clipper_dia + clipper_dist), y * (clipper_dia + clipper_dist), 0])
+            translate([(clipper_dia + clipper_dist) / 2, (clipper_dia + clipper_dist) / 2, clipper_floor])
+            clipper();
+        }
+    }
+}

coffe_grinder_adapter.scad

@@ -0,0 +1,86 @@
+compensate_dia = 0.5;
+compensate_width = 0.5;
+
+teeth = 12;
+tooth_dia = 2.75 + compensate_dia;
+tooth_off = (17.3 + compensate_width - tooth_dia) / 2;
+gear_h = 15.0;
+
+adapter_wall = 5;
+adapter_dia = tooth_off * 2 + tooth_dia + adapter_wall;
+adapter_h = gear_h + adapter_wall;
+
+use_male_socket = false;
+
+// male socket
+socket_h = gear_h;
+socket_dia = 7.0;
+socket_fn = 6;
+socket_flare = 3.0;
+
+// female socket
+sock_h = 10.0;
+sock_w = 6.4 + 0.4;
+sock_imp_d = 0.6 + 0.1;
+sock_imp_o = 4.0;
+sock_imp_w = 3.0;
+sock_imp_d2 = 0.4;
+
+$fn = 42;
+
+module gear(h) {
+    cylinder(d = tooth_off * 2, h = h);
+    
+    for (r = [0 : 360 / teeth : 360])
+    rotate([0, 0, r])
+    translate([tooth_off, 0, 0])
+    cylinder(d = tooth_dia, h = h);
+}
+
+module female_socket() {
+    difference() {
+        cylinder(d = adapter_dia, h = sock_h + 0.1);
+        
+        translate([-sock_w / 2, -sock_w / 2, 0.1])
+        cube([sock_w, sock_w, sock_h + 1]);
+        
+        translate([sock_w / 2, 0, sock_imp_o + 0.1])
+        sphere(d = 2 * sock_imp_d);
+        
+        translate([sock_w / 2, 0, sock_imp_o + 0.1])
+        cylinder(d = 2 * sock_imp_d2, h = sock_h);
+    }
+}
+
+module adapter() {
+    difference() {
+        union() {
+            cylinder(d = adapter_dia, h = adapter_h);
+    
+            if (use_male_socket)
+            translate([0, 0, adapter_h]) {
+                cylinder(d = socket_dia, h = socket_h, $fn = socket_fn);
+                
+                hull() {
+                    cylinder(d = socket_dia, h = socket_flare, $fn = socket_fn);
+                    translate([0, 0, -socket_flare])
+                    cylinder(d = adapter_dia, h = socket_flare);
+                }
+            }
+        }
+        
+        translate([0, 0, -1])
+        gear(gear_h + 1);
+        
+        if (use_male_socket)
+        translate([0, 0, gear_h - 0.1])
+        cylinder(d1 = tooth_off * 2 + tooth_dia, d2 = 5, h = socket_flare * 2 + 0.1);
+    }
+    
+    if (!use_male_socket)
+    translate([0, 0, adapter_h])
+    female_socket();
+}
+
+//gear(gear_h);
+adapter();

coffee_mill.scad

@@ -0,0 +1,150 @@
+mill_h = 136;
+mill_do = 54.9;
+mill_di = 48.7;
+mill_ih = 13.4;
+
+hat_do_bot = mill_di - 1;
+hat_h_bot = mill_ih - 1;
+hat_do_top = mill_do;
+hat_h_top = 5;
+hat_wall = 3;
+hat_di_bot = hat_do_bot - 2 * hat_wall;
+
+boot_wall = 3;
+boot_h = 20;
+boot_support = 5;
+boot_di_min = mill_do + 1;
+boot_di_max = boot_di_min + 20;
+boot_do_min = boot_di_min + 2 * boot_wall;
+boot_do_max = boot_di_max + 2 * boot_wall;
+
+rubber_ridge_w = 3;
+rubber_ridge_h = 2;
+
+mode = "print"; // [ "hat", "boot", "assembly", "assembly_cut", "print" ]
+prev_mode = "inverted"; // [ "normal", "inverted" ]
+
+$fn = $preview ? 42 : 100;
+
+module mill() {
+    difference() {
+        cylinder(d = mill_do, h = mill_h);
+
+        translate([0, 0, mill_h - mill_ih])
+        cylinder(d = mill_di, h = mill_ih + 0.1);
+
+        translate([0, 0, 5])
+        cylinder(d = mill_di, h = mill_h - mill_ih - 10);
+    }
+}
+
+module hat() {
+    difference() {
+        cylinder(d = hat_do_bot, h = hat_h_bot + 0.1);
+
+        translate([0, 0, -0.1])
+        cylinder(d = hat_di_bot, h = hat_h_bot + 0.2);
+    }
+
+    translate([0, 0, hat_h_bot])
+    difference() {
+        cylinder(d = hat_do_top, h = hat_h_top);
+        
+        translate([0, 0, hat_h_top - rubber_ridge_h / 2])
+        for (r = [0, 90])
+        rotate([0, 0, r])
+        cube([rubber_ridge_w, hat_do_top + 0.2, rubber_ridge_h + 0.1], center = true);
+    }
+}
+
+module boot() {
+    difference() {
+        union() {
+            cylinder(d = boot_do_min, h = boot_wall);
+
+            translate([0, 0, boot_wall])
+            cylinder(d1 = boot_do_min, d2 = boot_do_max, h = boot_h);
+        }
+
+        translate([0, 0, boot_wall - 0.1])
+        cylinder(d1 = boot_di_min, d2 = boot_di_max, h = boot_h + 0.2);
+        
+        translate([0, 0, -0.1])
+        cylinder(d = boot_di_min, h = boot_wall + 0.2);
+    }
+
+    translate([0, 0, boot_wall / 2])
+    for (r = [0, 90])
+    rotate([0, 0, r])
+    cube([boot_di_min, boot_support, boot_wall], center = true);
+
+    translate([0, 0, -boot_wall])
+    difference() {
+        cylinder(d = hat_do_bot, h = boot_wall);
+        translate([0, 0, -0.1])
+        cylinder(d = hat_do_bot - 2 * boot_wall, h = boot_wall + 0.2);
+    }
+
+    translate([0, 0, -boot_wall])
+    difference() {
+        cylinder(d = boot_do_min, h = boot_wall);
+        translate([0, 0, -0.1])
+        cylinder(d = boot_di_min, h = boot_wall + 0.2);
+
+        translate([0, 0, rubber_ridge_h / 2])
+        for (r = [0, 90])
+        rotate([0, 0, r])
+        cube([rubber_ridge_w, boot_do_min + 0.2, rubber_ridge_h + 0.1], center = true);
+    }
+
+    translate([0, 0, -boot_wall + boot_wall / 2])
+    for (r = [0, 90])
+    rotate([0, 0, r])
+    cube([hat_do_bot - 2 * boot_wall, boot_support, boot_wall], center = true);
+}
+
+module assembly() {
+    color("blue")
+    if ($preview)
+    translate([0, 0, boot_wall])
+    mill();
+
+    if (prev_mode == "normal") {
+        color("red")
+        translate([0, 0, mill_h - hat_h_bot + boot_wall + 0.2])
+        hat();
+        
+        color("green")
+        boot();
+    } else if (prev_mode == "inverted") {
+        color("green")
+        translate([0, 0, mill_h + boot_wall])
+        boot();
+    }
+}
+
+module print() {
+    translate([0, 0, hat_h_bot + hat_h_top])
+    rotate([180, 0, 0])
+    hat();
+
+    translate([hat_do_top / 2 + boot_do_max / 2 + 5, 0, boot_wall])
+    boot();
+}
+
+if (mode == "hat") {
+    hat();
+} else if (mode == "boot") {
+    boot();
+} else if (mode == "print") {
+    print();
+} else if (mode == "assembly") {
+    assembly();
+} else if (mode == "assembly_cut") {
+    difference() {
+        assembly();
+
+        translate([-100, 0, -10])
+        cube([200, 100, 200]);
+    }
+}

crafty_usb_c.scad

@@ -0,0 +1,56 @@
+w = 13.0;
+d = 12.0;
+h = 21.0;
+
+cut = 4.0;
+hole = 2.25;
+off = 13.0;
+
+usb_dia = 5.8;
+usb_w = 11.0;
+usb_off = 1.5;
+
+$fn = 42;
+
+usb_bottom_h = 4.5 + 1.5;
+usb_w_bottom = 7.7;
+
+module usb_internal(h, w) {
+    translate([(usb_dia - w) / 2, 0, 0]) {
+        cylinder(d = usb_dia, h = h);
+        
+        translate([w - usb_dia, 0, 0])
+        cylinder(d = usb_dia, h = h);
+        
+        translate([0, -usb_dia / 2, 0])
+        cube([w - usb_dia, usb_dia, h]);
+    }
+}
+
+module usb(h) {
+    hull() {
+        translate([0, 0, usb_bottom_h])
+        usb_internal(h - usb_bottom_h, usb_w);
+        
+        usb_internal(usb_bottom_h, usb_w_bottom);
+    }
+}
+
+module holder() {
+    difference() {
+        cube([w, d, h]);
+        
+        translate([w / 2, -1, off])
+        rotate([-90, 0, 0])
+        cylinder(d = hole, h = d + 2);
+        
+        translate([(w - cut) / 2, -1, -1])
+        cube([cut, 5, h + 2]);
+        
+        translate([w / 2, usb_dia / 2 + usb_off, -1])
+        usb(h + 2);
+    }
+}
+
+//usb(20);
+holder();

dabrig.scad

@@ -0,0 +1,121 @@
+ba_l = 17;
+ba_d = 8.5;
+
+gap = 1.5;
+
+m_di = 52 + gap;
+m_wall = 6;
+m_do = m_di + m_wall;
+m_h = 42;
+ma_d = ba_d + gap;
+ma_ha = gap;
+
+t_dl = 5.5;
+t_ds = 3.6;
+t_h = 42;
+
+th_dl = t_dl + 1;
+th_ds = t_ds + 0.5;
+th_do = th_dl + 5;
+th_h = 20;
+th_ox = 5;
+
+v_d = 33;
+v_h = 19;
+
+tr_di = v_d + 1;
+tr_wall = m_wall;
+tr_do = tr_di + tr_wall;
+tr_h = v_h / 2;
+tr_ox = 5;
+
+th_r = 45;
+tr1_r = -45;
+tr2_r = -100;
+tr_r = [tr1_r, tr2_r];
+
+$fn = $preview ? 50 : 200;
+
+module pipe() {
+    // pipe body
+    translate([0, 0, -m_h])
+    cylinder(d = m_di - 2, h = m_h * 3);
+    
+    // arm
+    translate([0, (m_di - 2) / 2, ba_d / 2])
+    rotate([-90, 0, 0])
+    cylinder(d = ba_d, h = ba_l);
+    
+    // tool
+    rotate([0, 0, th_r])
+    translate([(m_do + th_do) / 2 + th_ox, 0, (m_h - th_h) / 2 - t_h / 4])
+    cylinder(d1 = t_ds, d2 = t_dl, h = t_h);
+    
+    // vat
+    for (r = tr_r)
+    rotate([0, 0, r])
+    translate([(m_do + tr_do) / 2 + tr_ox, 0, (m_h - tr_h) / 2])
+    cylinder(d = v_d, h = v_h);
+}
+
+module ring() {
+    difference() {
+        hull() {
+            // main body
+            cylinder(d = m_do, h = m_h);
+            
+            // tool holder
+            rotate([0, 0, th_r])
+            translate([(m_do + th_do) / 2 + th_ox, 0, (m_h - th_h) / 2])
+            cylinder(d = th_do, h = th_h);
+            
+            // tray
+            for (r = tr_r)
+            rotate([0, 0, r])
+            translate([(m_do + tr_do) / 2 + tr_ox, 0, (m_h - tr_h) / 2 - tr_wall])
+            cylinder(d = tr_do, h = tr_wall + tr_h);
+            
+        }
+        
+        // vat body
+        for (r = tr_r)
+        rotate([0, 0, r])
+        translate([(m_do + tr_do) / 2 + tr_ox, 0, (m_h - tr_h) / 2])
+        cylinder(d = tr_di, h = v_h + 20);
+        
+        // vat easing
+        for (r = tr_r)
+        rotate([0, 0, r])
+        translate([(m_do + tr_do) / 2 + tr_ox, 0, (m_h - tr_h) / 2 + tr_h - 2])
+        cylinder(d1 = tr_di, d2 = tr_di + 30, h = 30);
+        
+        // pipe body
+        translate([0, 0, -20])
+        cylinder(d = m_di, h = m_h + 40);
+        
+        // tool holder - bottom
+        rotate([0, 0, th_r])
+        translate([(m_do + th_do) / 2 + th_ox, 0, (m_h - th_h) / 2 - 20])
+        cylinder(d = th_ds, h = 20);
+        
+        // tool holder - top
+        rotate([0, 0, th_r])
+        translate([(m_do + th_do) / 2 + th_ox, 0, (m_h - th_h) / 2 + th_h])
+        cylinder(d = th_dl, h = 20);
+        
+        // tool holder - middle
+        rotate([0, 0, th_r])
+        translate([(m_do + th_do) / 2 + th_ox, 0, (m_h - th_h) / 2 - ($preview ? 0.1 : 0)])
+        cylinder(d1 = th_ds, d2 = th_dl, h = th_h + ($preview ? 0.2 : 0));
+        
+        // arm cutout
+        for (z = [-ma_d / 2 : ma_ha])
+        translate([0, (m_di - m_wall) / 2, ma_d / 2 + z])
+        rotate([-90, 0, 0])
+        cylinder(d = ma_d, h = m_wall * 2);
+        
+    }
+}
+
+%pipe();
+ring();