initial commit

hardware/external/cherry_mx.scad

@@ -0,0 +1,134 @@
+$fn=60;
+/**
+a cherry mx switch.
+
+most of the measurements done with a caliper. some taken from
+http://geekhack.org/index.php?topic=47744.0
+
+This is just to illustrate and to drop in a a gross reference. It is mostly artistic apart from the steam and mounting plate dimensions
+*/
+
+// slightly adapted from https://www.thingiverse.com/thing:421524
+
+module mx_switch(t = 0) {
+
+translate([0, 0, 9.25])
+//translate([0,0,-3])
+{
+
+	//1. steam
+	color("#503000")
+    translate([0, 0, -3.9 * t]) {
+		//1.1. l-r tab is 1.35mm
+		translate([0,0,-3.62/2])
+			cube([1.35,4.5,3.62], center=true);
+		//1.2. f-b tab is 1.15mm. it has a smal notch that i will ignore.
+		translate([0,0,-3.62/2])
+			cube([4.5,1.15,3.62], center=true);
+		//1.3. base. it has a chamfered top that i will ignore.
+		translate([0,0,-5.62])
+			cube([7.2,5.56,4], center=true);
+	}
+	// 2. top
+	color("grey"){
+		difference(){
+			// make a trapezoid with the general shape (volume?) of the top
+			hull(){
+				translate([0,0,-4]) //distance from top of switch... some i measured 3.9 others 4.2... so leaving at 4
+					cube([9.87,10.62,0.1], center=true);
+				translate([0,0,-4 -5.2]) // bottom has a measured 5.3... so move 5.2 and use the 0.1 bellow
+					cube([14.58,14.58,0.1], center=true);
+			}
+            
+			translate([0, 0, -5.8])
+            cube([7.2,5.56,4], center=true);
+            
+
+		// and subtract:
+		// the front led. NOTE: totally off... measured by eye. just for astetics
+		// adding just so there is a visual cue of the direction
+			translate([0,-4.7,-6])
+				cylinder(r=3/2, h=6, center=true);
+			translate([0,-5.5,-6])
+				cube([8,4,5], center=true);
+		// the four corners
+			// TODO waste of time? this is all for looks, you shouldn't invade any of that space anyway...
+		}
+	}
+
+	// 3. bottom
+	color("green")
+		// 3.1 main body volume
+		hull(){
+				translate([0,0,-4 -5.3]) //steam + top
+					cube([13.98,13.98,0.1], center=true);
+				translate([0,0,-4 -5.3 -2.2]) //steam + top + straigth part
+					cube([13.98,13.98,0.1], center=true);
+				translate([0,0,-4 -5.3 -5.5]) //steam + top + bottom (measured 5.5)
+					cube([12.74,13.6,0.1], center=true);
+		}
+		// 3.2 tabs
+		// note: only measured the lenght, if they are slightly off-center, this will be all wrong :)
+		color("black")
+		difference(){
+			translate([0,0,-4 -5.3 -0.82/2]) //steam + top
+				cube([15.64,15.64,0.82], center=true);
+			translate([0,0,-4 -5.3 -0.82/2  ]) // front-back cut
+				cube([5.64,20,0.82 +2], center=true);
+			translate([0,0,-4 -5.3 -0.82/2  ]) //side cut
+				cube([20,11.64,0.82 +2], center=true);
+		}
+
+		// 3.3 tab (plate snap on). to use this mechanically, you have to take into account the bending (as it will move the bottom part slightly up...) just for gross reference here for now
+		color("white"){
+			// 3.3.1 top
+			translate([0,0,-4 -5.3 -0.82/2  ]) // front-back cut
+				cube([1.82,16.33,0.82], center=true);
+			// 3.3.2 bottom
+			difference(){
+				hull(){
+					translate([0,0,-4 -5.3 -0.82/2 -1.76  ]) // front-back cut
+						cube([3.65,14,0.1], center=true);
+					translate([0,0,-4 -5.3 -0.82/2 -2.2  ]) // front-back cut
+						cube([3.65,14.74,0.1], center=true);
+					translate([0,0,-4 -5.3 -0.82/2 -2.89  ]) // front-back cut
+						cube([3.65,14,0.1], center=true);
+				}
+				translate([0,0,-4 -5.3 -0.82/2 -1.76   ]) // front-back cut
+					cube([2.2,20,4], center=true);
+
+			}
+		}
+
+		// 4. bottom guides
+		// again, i'm assuming everything is centered...
+		color("darkGreen"){
+			// 4.1 cylinder
+			translate([0,0,-4 -5.3 -5.5 -2/2]) //steam + top + bottom (measured 5.5)
+				cylinder(r=3.85/2, h=2, center=true);
+			translate([0,0,-4 -5.3 -5.5 -2 -1/2]) //steam + top + bottom (measured 5.5)
+				cylinder(r2=3.85/2, r1=2.8/2, h=1, center=true);
+			// 4.2 PCB pins
+			translate([4.95,0,-4 -5.3 -5.5 -2/2]) //steam + top + bottom (measured 5.5)
+				cylinder(r=1.6/2, h=2, center=true);
+			translate([4.95,0,-4 -5.3 -5.5 -2 -1/2]) //steam + top + bottom (measured 5.5)
+				cylinder(r2=1.6/2, r1=1/2, h=1, center=true);
+			translate([-4.95,0,-4 -5.3 -5.5 -2/2]) //steam + top + bottom (measured 5.5)
+				cylinder(r=1.6/2, h=2, center=true);
+			translate([-4.95,0,-4 -5.3 -5.5 -2 -1/2]) //steam + top + bottom (measured 5.5)
+				cylinder(r2=1.6/2, r1=1/2, h=1, center=true);
+		}
+
+		// 5. pins
+		color("orange"){
+			translate([-3.77,2.7,-4 -5.3 -5.5 -3.1/2]) //steam + top + bottom (measured 5.5)
+				cube([.86, 0.2,3.1], center=true);
+			translate([2.7,5.2,-4 -5.3 -5.5 -3.1/2]) //steam + top + bottom (measured 5.5)
+				cube([.86, 0.2,3.1], center=true);
+		}
+
+}
+
+}
+
+mx_switch();

hardware/external/threads.scad

@@ -0,0 +1,431 @@
+/*
+ * ISO-standard metric threads, following this specification:
+ *          http://en.wikipedia.org/wiki/ISO_metric_screw_thread
+ *
+ * Copyright 2022 Dan Kirshner - dan_kirshner@yahoo.com
+ * This program is free software: you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation, either version 3 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * See <http://www.gnu.org/licenses/>.
+ *
+ * Version 2.7.  2022-02-27  Increase minimum thread segments.
+ * Version 2.6.  2021-05-16  Contributed patches for leadin (thanks,
+                             jeffery.spirko@tamucc.edu) and aligning thread
+                             "facets" (triangulation) with base cylinder
+                             (thanks, rambetter@protonmail.com).
+ * Version 2.5.  2020-04-11  Leadin option works for internal threads.
+ * Version 2.4.  2019-07-14  Add test option - do not render threads.
+ * Version 2.3.  2017-08-31  Default for leadin: 0 (best for internal threads).
+ * Version 2.2.  2017-01-01  Correction for angle; leadfac option.  (Thanks to
+ *                           Andrew Allen <a2intl@gmail.com>.)
+ * Version 2.1.  2016-12-04  Chamfer bottom end (low-z); leadin option.
+ * Version 2.0.  2016-11-05  Backwards compatibility (earlier OpenSCAD) fixes.
+ * Version 1.9.  2016-07-03  Option: tapered.
+ * Version 1.8.  2016-01-08  Option: (non-standard) angle.
+ * Version 1.7.  2015-11-28  Larger x-increment - for small-diameters.
+ * Version 1.6.  2015-09-01  Options: square threads, rectangular threads.
+ * Version 1.5.  2015-06-12  Options: thread_size, groove.
+ * Version 1.4.  2014-10-17  Use "faces" instead of "triangles" for polyhedron
+ * Version 1.3.  2013-12-01  Correct loop over turns -- don't have early cut-off
+ * Version 1.2.  2012-09-09  Use discrete polyhedra rather than linear_extrude ()
+ * Version 1.1.  2012-09-07  Corrected to right-hand threads!
+ */
+
+// Examples.
+//
+// Standard M8 x 1.
+// metric_thread (diameter=8, pitch=1, length=4);
+
+// Square thread.
+// metric_thread (diameter=8, pitch=1, length=4, square=true);
+
+// Non-standard: long pitch, same thread size.
+//metric_thread (diameter=8, pitch=4, length=4, thread_size=1, groove=true);
+
+// Non-standard: 20 mm diameter, long pitch, square "trough" width 3 mm,
+// depth 1 mm.
+//metric_thread (diameter=20, pitch=8, length=16, square=true, thread_size=6,
+//               groove=true, rectangle=0.333);
+
+// English: 1/4 x 20.
+//english_thread (diameter=1/4, threads_per_inch=20, length=1);
+
+// Tapered.  Example -- pipe size 3/4" -- per:
+// http://www.engineeringtoolbox.com/npt-national-pipe-taper-threads-d_750.html
+// english_thread (diameter=1.05, threads_per_inch=14, length=3/4, taper=1/16);
+
+// Thread for mounting on Rohloff hub.
+//difference () {
+//   cylinder (r=20, h=10, $fn=100);
+//
+//   metric_thread (diameter=34, pitch=1, length=10, internal=true, n_starts=6);
+//}
+
+
+// ----------------------------------------------------------------------------
+function segments (diameter) = min (150, max (ceil (diameter*6), 25));
+
+
+// ----------------------------------------------------------------------------
+// diameter -    outside diameter of threads in mm. Default: 8.
+// pitch    -    thread axial "travel" per turn in mm.  Default: 1.
+// length   -    overall axial length of thread in mm.  Default: 1.
+// internal -    true = clearances for internal thread (e.g., a nut).
+//               false = clearances for external thread (e.g., a bolt).
+//               (Internal threads should be "cut out" from a solid using
+//               difference ()).  Default: false.
+// n_starts -    Number of thread starts (e.g., DNA, a "double helix," has
+//               n_starts=2).  See wikipedia Screw_thread.  Default: 1.
+// thread_size - (non-standard) axial width of a single thread "V" - independent
+//               of pitch.  Default: same as pitch.
+// groove      - (non-standard) true = subtract inverted "V" from cylinder
+//                (rather thanadd protruding "V" to cylinder).  Default: false.
+// square      - true = square threads (per
+//               https://en.wikipedia.org/wiki/Square_thread_form).  Default:
+//               false.
+// rectangle   - (non-standard) "Rectangular" thread - ratio depth/(axial) width
+//               Default: 0 (standard "v" thread).
+// angle       - (non-standard) angle (deg) of thread side from perpendicular to
+//               axis (default = standard = 30 degrees).
+// taper       - diameter change per length (National Pipe Thread/ANSI B1.20.1
+//               is 1" diameter per 16" length). Taper decreases from 'diameter'
+//               as z increases.  Default: 0 (no taper).
+// leadin      - 0 (default): no chamfer; 1: chamfer (45 degree) at max-z end;
+//               2: chamfer at both ends, 3: chamfer at z=0 end.
+// leadfac     - scale of leadin chamfer length (default: 1.0 = 1/2 thread).
+// test        - true = do not render threads (just draw "blank" cylinder).
+//               Default: false (draw threads).
+module metric_thread (diameter=8, pitch=1, length=1, internal=false, n_starts=1,
+                      thread_size=-1, groove=false, square=false, rectangle=0,
+                      angle=30, taper=0, leadin=0, leadfac=1.0, test=false)
+{
+   // thread_size: size of thread "V" different than travel per turn (pitch).
+   // Default: same as pitch.
+   local_thread_size = thread_size == -1 ? pitch : thread_size;
+   local_rectangle = rectangle ? rectangle : 1;
+
+   n_segments = segments (diameter);
+   h = (test && ! internal) ? 0 : (square || rectangle) ? local_thread_size*local_rectangle/2 : local_thread_size / (2 * tan(angle));
+
+   h_fac1 = (square || rectangle) ? 0.90 : 0.625;
+
+   // External thread includes additional relief.
+   h_fac2 = (square || rectangle) ? 0.95 : 5.3/8;
+
+   tapered_diameter = diameter - length*taper;
+
+   difference () {
+      union () {
+         if (! groove) {
+            if (! test) {
+               metric_thread_turns (diameter, pitch, length, internal, n_starts,
+                                    local_thread_size, groove, square, rectangle, angle,
+                                    taper);
+            }
+         }
+
+         difference () {
+
+            // Solid center, including Dmin truncation.
+            if (groove) {
+               cylinder (r1=diameter/2, r2=tapered_diameter/2,
+                         h=length, $fn=n_segments);
+            } else if (internal) {
+               cylinder (r1=diameter/2 - h*h_fac1, r2=tapered_diameter/2 - h*h_fac1,
+                         h=length, $fn=n_segments);
+            } else {
+
+               // External thread.
+               cylinder (r1=diameter/2 - h*h_fac2, r2=tapered_diameter/2 - h*h_fac2,
+                         h=length, $fn=n_segments);
+            }
+
+            if (groove) {
+               if (! test) {
+                  metric_thread_turns (diameter, pitch, length, internal, n_starts,
+                                       local_thread_size, groove, square, rectangle,
+                                       angle, taper);
+               }
+            }
+         }
+
+         // Internal thread lead-in: take away from external solid.
+         if (internal) {
+
+            // "Negative chamfer" z=0 end if leadin is 2 or 3.
+            if (leadin == 2 || leadin == 3) {
+
+               // Fixes by jeffery.spirko@tamucc.edu.
+               cylinder (r1=diameter/2 - h + h*h_fac1*leadfac,
+                         r2=diameter/2 - h,
+                         h=h*h_fac1*leadfac, $fn=n_segments);
+               /*
+               cylinder (r1=diameter/2,
+                         r2=diameter/2 - h*h_fac1*leadfac,
+                         h=h*h_fac1*leadfac, $fn=n_segments);
+               */
+            }
+
+            // "Negative chamfer" z-max end if leadin is 1 or 2.
+            if (leadin == 1 || leadin == 2) {
+               translate ([0, 0, length + 0.05 - h*h_fac1*leadfac]) {
+
+                  cylinder (r1=tapered_diameter/2 - h,
+                            h=h*h_fac1*leadfac,
+                            r2=tapered_diameter/2 - h + h*h_fac1*leadfac,
+                            $fn=n_segments);
+                  /*
+                  cylinder (r1=tapered_diameter/2 - h*h_fac1*leadfac,
+                            h=h*h_fac1*leadfac,
+                            r2=tapered_diameter/2,
+                            $fn=n_segments);
+                  */
+               }
+            }
+         }
+      }
+
+      if (! internal) {
+
+         // Chamfer z=0 end if leadin is 2 or 3.
+         if (leadin == 2 || leadin == 3) {
+            difference () {
+               cylinder (r=diameter/2 + 1, h=h*h_fac1*leadfac, $fn=n_segments);
+
+               cylinder (r2=diameter/2, r1=diameter/2 - h*h_fac1*leadfac, h=h*h_fac1*leadfac,
+                         $fn=n_segments);
+            }
+         }
+
+         // Chamfer z-max end if leadin is 1 or 2.
+         if (leadin == 1 || leadin == 2) {
+            translate ([0, 0, length + 0.05 - h*h_fac1*leadfac]) {
+               difference () {
+                  cylinder (r=diameter/2 + 1, h=h*h_fac1*leadfac, $fn=n_segments);
+
+                  cylinder (r1=tapered_diameter/2, r2=tapered_diameter/2 - h*h_fac1*leadfac, h=h*h_fac1*leadfac,
+                            $fn=n_segments);
+               }
+            }
+         }
+      }
+   }
+}
+
+
+// ----------------------------------------------------------------------------
+// Input units in inches.
+// Note: units of measure in drawing are mm!
+module english_thread (diameter=0.25, threads_per_inch=20, length=1,
+                      internal=false, n_starts=1, thread_size=-1, groove=false,
+                      square=false, rectangle=0, angle=30, taper=0, leadin=0,
+                      leadfac=1.0, test=false)
+{
+   // Convert to mm.
+   mm_diameter = diameter*25.4;
+   mm_pitch = (1.0/threads_per_inch)*25.4;
+   mm_length = length*25.4;
+
+   echo (str ("mm_diameter: ", mm_diameter));
+   echo (str ("mm_pitch: ", mm_pitch));
+   echo (str ("mm_length: ", mm_length));
+   metric_thread (mm_diameter, mm_pitch, mm_length, internal, n_starts,
+                  thread_size, groove, square, rectangle, angle, taper, leadin,
+                  leadfac, test);
+}
+
+// ----------------------------------------------------------------------------
+module metric_thread_turns (diameter, pitch, length, internal, n_starts,
+                            thread_size, groove, square, rectangle, angle,
+                            taper)
+{
+   // Number of turns needed.
+   n_turns = floor (length/pitch);
+
+   intersection () {
+
+      // Start one below z = 0.  Gives an extra turn at each end.
+      for (i=[-1*n_starts : n_turns+1]) {
+         translate ([0, 0, i*pitch]) {
+            metric_thread_turn (diameter, pitch, internal, n_starts,
+                                thread_size, groove, square, rectangle, angle,
+                                taper, i*pitch);
+         }
+      }
+
+      // Cut to length.
+      translate ([0, 0, length/2]) {
+         cube ([diameter*3, diameter*3, length], center=true);
+      }
+   }
+}
+
+
+// ----------------------------------------------------------------------------
+module metric_thread_turn (diameter, pitch, internal, n_starts, thread_size,
+                           groove, square, rectangle, angle, taper, z)
+{
+   n_segments = segments (diameter);
+   fraction_circle = 1.0/n_segments;
+   for (i=[0 : n_segments-1]) {
+
+      // Keep polyhedron "facets" aligned -- circumferentially -- with base
+      // cylinder facets.  (Patch contributed by rambetter@protonmail.com.)
+      rotate ([0, 0, (i + 0.5)*360*fraction_circle + 90]) {
+         translate ([0, 0, i*n_starts*pitch*fraction_circle]) {
+            //current_diameter = diameter - taper*(z + i*n_starts*pitch*fraction_circle);
+            thread_polyhedron ((diameter - taper*(z + i*n_starts*pitch*fraction_circle))/2,
+                               pitch, internal, n_starts, thread_size, groove,
+                               square, rectangle, angle);
+         }
+      }
+   }
+}
+
+
+// ----------------------------------------------------------------------------
+module thread_polyhedron (radius, pitch, internal, n_starts, thread_size,
+                          groove, square, rectangle, angle)
+{
+   n_segments = segments (radius*2);
+   fraction_circle = 1.0/n_segments;
+
+   local_rectangle = rectangle ? rectangle : 1;
+
+   h = (square || rectangle) ? thread_size*local_rectangle/2 : thread_size / (2 * tan(angle));
+   outer_r = radius + (internal ? h/20 : 0); // Adds internal relief.
+   //echo (str ("outer_r: ", outer_r));
+
+   // A little extra on square thread -- make sure overlaps cylinder.
+   h_fac1 = (square || rectangle) ? 1.1 : 0.875;
+   inner_r = radius - h*h_fac1; // Does NOT do Dmin_truncation - do later with
+                                // cylinder.
+
+   translate_y = groove ? outer_r + inner_r : 0;
+   reflect_x   = groove ? 1 : 0;
+
+   // Make these just slightly bigger (keep in proportion) so polyhedra will
+   // overlap.
+   x_incr_outer = (! groove ? outer_r : inner_r) * fraction_circle * 2 * PI * 1.02;
+   x_incr_inner = (! groove ? inner_r : outer_r) * fraction_circle * 2 * PI * 1.02;
+   z_incr = n_starts * pitch * fraction_circle * 1.005;
+
+   /*
+    (angles x0 and x3 inner are actually 60 deg)
+
+                          /\  (x2_inner, z2_inner) [2]
+                         /  \
+   (x3_inner, z3_inner) /    \
+                  [3]   \     \
+                        |\     \ (x2_outer, z2_outer) [6]
+                        | \    /
+                        |  \  /|
+             z          |[7]\/ / (x1_outer, z1_outer) [5]
+             |          |   | /
+             |   x      |   |/
+             |  /       |   / (x0_outer, z0_outer) [4]
+             | /        |  /     (behind: (x1_inner, z1_inner) [1]
+             |/         | /
+    y________|          |/
+   (r)                  / (x0_inner, z0_inner) [0]
+
+   */
+
+   x1_outer = outer_r * fraction_circle * 2 * PI;
+
+   z0_outer = (outer_r - inner_r) * tan(angle);
+   //echo (str ("z0_outer: ", z0_outer));
+
+   //polygon ([[inner_r, 0], [outer_r, z0_outer],
+   //        [outer_r, 0.5*pitch], [inner_r, 0.5*pitch]]);
+   z1_outer = z0_outer + z_incr;
+
+   // Give internal square threads some clearance in the z direction, too.
+   bottom = internal ? 0.235 : 0.25;
+   top    = internal ? 0.765 : 0.75;
+
+   translate ([0, translate_y, 0]) {
+      mirror ([reflect_x, 0, 0]) {
+
+         if (square || rectangle) {
+
+            // Rule for face ordering: look at polyhedron from outside: points must
+            // be in clockwise order.
+            polyhedron (
+               points = [
+                         [-x_incr_inner/2, -inner_r, bottom*thread_size],         // [0]
+                         [x_incr_inner/2, -inner_r, bottom*thread_size + z_incr], // [1]
+                         [x_incr_inner/2, -inner_r, top*thread_size + z_incr],    // [2]
+                         [-x_incr_inner/2, -inner_r, top*thread_size],            // [3]
+
+                         [-x_incr_outer/2, -outer_r, bottom*thread_size],         // [4]
+                         [x_incr_outer/2, -outer_r, bottom*thread_size + z_incr], // [5]
+                         [x_incr_outer/2, -outer_r, top*thread_size + z_incr],    // [6]
+                         [-x_incr_outer/2, -outer_r, top*thread_size]             // [7]
+                        ],
+
+               faces = [
+                         [0, 3, 7, 4],  // This-side trapezoid
+
+                         [1, 5, 6, 2],  // Back-side trapezoid
+
+                         [0, 1, 2, 3],  // Inner rectangle
+
+                         [4, 7, 6, 5],  // Outer rectangle
+
+                         // These are not planar, so do with separate triangles.
+                         [7, 2, 6],     // Upper rectangle, bottom
+                         [7, 3, 2],     // Upper rectangle, top
+
+                         [0, 5, 1],     // Lower rectangle, bottom
+                         [0, 4, 5]      // Lower rectangle, top
+                        ]
+            );
+         } else {
+
+            // Rule for face ordering: look at polyhedron from outside: points must
+            // be in clockwise order.
+            polyhedron (
+               points = [
+                         [-x_incr_inner/2, -inner_r, 0],                        // [0]
+                         [x_incr_inner/2, -inner_r, z_incr],                    // [1]
+                         [x_incr_inner/2, -inner_r, thread_size + z_incr],      // [2]
+                         [-x_incr_inner/2, -inner_r, thread_size],              // [3]
+
+                         [-x_incr_outer/2, -outer_r, z0_outer],                 // [4]
+                         [x_incr_outer/2, -outer_r, z0_outer + z_incr],         // [5]
+                         [x_incr_outer/2, -outer_r, thread_size - z0_outer + z_incr], // [6]
+                         [-x_incr_outer/2, -outer_r, thread_size - z0_outer]    // [7]
+                        ],
+
+               faces = [
+                         [0, 3, 7, 4],  // This-side trapezoid
+
+                         [1, 5, 6, 2],  // Back-side trapezoid
+
+                         [0, 1, 2, 3],  // Inner rectangle
+
+                         [4, 7, 6, 5],  // Outer rectangle
+
+                         // These are not planar, so do with separate triangles.
+                         [7, 2, 6],     // Upper rectangle, bottom
+                         [7, 3, 2],     // Upper rectangle, top
+
+                         [0, 5, 1],     // Lower rectangle, bottom
+                         [0, 4, 5]      // Lower rectangle, top
+                        ]
+            );
+         }
+      }
+   }
+}
+
+
+

hardware/trackball.scad

@@ -0,0 +1,359 @@
+/*
+ * Trackball
+ * Copyright 2022 Thomas Buck - thomas@xythobuz.de
+ *
+ * Required parts:
+ *  - 1x Raspberry Pi Pico
+ *  - 5x Cherry MX compatible switches and keycaps
+ *  - 1x Billard ball, diameter 38mm 
+ *  - 3x Si3N4 static bearing balls, diameter 3mm
+ *  - 3x spring, diameter 2mm, length 10mm
+ *  - 1x PMW3360 sensor with breakout board
+ *  - 8x M2 screw, length 5mm
+ *  - 8x M2 heat melt insert, length 4mm
+ *
+ * For the PMW3360 breakout board get this:
+ * https://github.com/jfedor2/pmw3360-breakout
+ *
+ * The "Threads" library used by this project is:
+ * Copyright 2022 Dan Kirshner - dan_kirshner@yahoo.com
+ *
+ * This program is free software: you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation, either version 3 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * See <http://www.gnu.org/licenses/>.
+ */
+
+// https://www.thingiverse.com/thing:421524
+use <external/cherry_mx.scad>
+
+// https://dkprojects.net/openscad-threads/
+use <external/threads.scad>
+
+// #######################
+// #### Configuration ####
+// #######################
+
+ball_dia = 38.0;
+roller_dia = 3.0;
+
+roller_ball_h = 8;
+roller_count = 3;
+
+wall = 3.0;
+
+cut_roller_holder = false;
+draw_threads = false;
+
+// #######################
+// ## Raspberry Pi Pico ##
+// #######################
+
+pico_w = 21;
+pico_l = 51;
+pico_d = 1.6; // todo
+pico_hole_d = 2.1;
+pico_hole_x = 4.8;
+pico_hole_y = 2.0;
+pico_hole_d_x = 11.4;
+pico_hole_d_y = pico_l - 2 * pico_hole_y;
+pico_usb_w = 8.0;
+pico_usb_h = 3.0; // todo
+pico_usb_d = 10.0; // todo
+pico_usb_off = 1.3;
+
+pico_h = pico_d + 1; // todo
+
+// ######################
+// ### PMW3360 Sensor ###
+// ######################
+
+// https://github.com/jfedor2/pmw3360-breakout
+sensor_w = 22;
+sensor_l = 34;
+sensor_pcb_h = 1.6;
+sensor_hole_dia = 2.2;
+sensor_hole_off_x = 3.0;
+sensor_hole_off_y = 3.0;
+sensor_hole_dist_x = 16.0;
+sensor_hole_dist_y = 24.5;
+sensor_cut_w = 8.0 + 0.5;
+sensor_cut_h = 17.26;
+sensor_cut_off_x = 7.0 - 0.25;
+sensor_cut_off_y = 5.27;
+sensor_cut_edge_to_pin1 = 2.75;
+sensor_edge_to_pin1 = 1.52;
+
+sensor_ball_to_lens_top = 2.4;
+sensor_ball_to_chip_bottom = 9.81;
+
+sensor_chip_w = 9.1;
+sensor_chip_l = 16.2;
+sensor_chip_h = 2.21;
+
+sensor_pin_w = 0.5;
+sensor_pin_h = 4.51;
+sensor_pin_d = 0.2;
+sensor_pin_dist = 10.7;
+sensor_pin_off_top = 0.5;
+sensor_pin_pitch = 0.89;
+
+sensor_pin1_to_optical_center = 5.66;
+
+// ######################
+// ## MX Switch Cutout ##
+// ######################
+
+// https://geekhack.org/index.php?topic=70654.0
+mx_co_w = 14.0;
+mx_co_w_add = 0.8;
+mx_co_h = 14.0;
+mx_co_h_off_1 = 1.0;
+mx_co_h_off_2 = 3.5;
+mx_co_h_off_3 = mx_co_h - 2 * (mx_co_h_off_1 + mx_co_h_off_2);
+mx_co_r = 0.4;
+
+// https://geekhack.org/index.php?topic=71550.0
+mx_co_th = 1.5 - 0.1;
+mx_co_b_add = 1.0;
+mx_co_b_w = mx_co_w + mx_co_b_add;
+mx_co_b_h = mx_co_h + mx_co_b_add;
+
+mx_travel = 3.9;
+
+// ######################
+// ### Implementation ###
+// ######################
+
+roller_thread_dia = roller_dia + 5.0;
+roller_thread_pitch = 2.0;
+roller_h = roller_dia + 7.0;
+roller_ball_h_off = 0.6;
+roller_ball_hold_off = 0.5;
+roller_thread_hole = roller_dia + 0.5;
+roller_small_hole = sphere_r_at_h(roller_ball_hold_off, roller_dia / 2) * 2;
+
+roller_ridge_h = 1.5;
+roller_mount_angle_off = 90;
+roller_mount_dia = roller_thread_dia + 2.0;
+
+ball_h = 15; // todo
+
+switch_test_w = 25;
+
+$fn = 42;
+
+function sphere_r_at_h(h, r) = r * sin(acos(h / r));
+function sphere_angle_at_rh(h, r) = acos(h / r);
+
+module mx_switch_cutout(h) {
+    translate([-mx_co_w / 2 - mx_co_w_add, -mx_co_h / 2, 0]) {
+        linear_extrude(h + 1) {
+            translate([mx_co_w_add, 0]) {
+                square([mx_co_w, mx_co_h]);
+                
+                for (x = [mx_co_r / 2, mx_co_w - mx_co_r / 2])
+                for (y = [mx_co_r / 2, mx_co_h - mx_co_r / 2])
+                translate([x, y])
+                circle(r = mx_co_r);
+            }
+            
+            for (x = [0, mx_co_w + mx_co_w_add])
+            for (y = [0, mx_co_h_off_2 + mx_co_h_off_3])
+            translate([x, mx_co_h_off_1 + y, 0])
+            square([mx_co_w_add, mx_co_h_off_2]);
+        }
+        
+        translate([mx_co_w_add - mx_co_b_add / 2, -mx_co_b_add / 2, -1])
+        cube([mx_co_b_w, mx_co_b_h, h - mx_co_th + 1]);
+    }
+}
+
+module mx_switch_test() {
+    difference() {
+        translate([-switch_test_w / 2, -switch_test_w / 2, 0])
+        cube([switch_test_w, switch_test_w, wall]);
+        
+        mx_switch_cutout(wall);
+        
+        translate([0, -switch_test_w / 2 + 1, wall - 1.0])
+        linear_extrude(1.1)
+        text("switch test", size = 3, halign = "center");
+    }
+    
+    %translate([0, 0, wall])
+    rotate([0, 0, 180])
+    mx_switch($t);
+}
+
+module pico() {
+    translate([-pico_w / 2, -pico_l / 2, 0])
+    difference() {
+        union() {
+            color("green")
+            cube([pico_w, pico_l, pico_d]);
+            
+            translate([(pico_w - pico_usb_w) / 2, pico_l - pico_usb_d + pico_usb_off, pico_d])
+            cube([pico_usb_w, pico_usb_d, pico_usb_h]);
+        }
+        
+        for (x = [0, pico_hole_d_x])
+        for (y = [0, pico_hole_d_y])
+        translate([pico_hole_x + x, pico_hole_y + y, -1])
+        cylinder(d = pico_hole_d, h = pico_d + 2);
+    }
+}
+
+module sensor() {
+    translate([-sensor_w / 2, -sensor_l / 2, 0])
+    difference() {
+        color("green")
+        cube([sensor_w, sensor_l, sensor_pcb_h]);
+        
+        translate([sensor_cut_off_x, sensor_cut_off_y, -1])
+        cube([sensor_cut_w, sensor_cut_h, sensor_pcb_h + 2]);
+        
+        for (x = [0, sensor_hole_dist_x])
+        for (y = [0, sensor_hole_dist_y])
+        translate([sensor_hole_off_x + x, sensor_hole_off_y + y, -1])
+        cylinder(d = sensor_hole_dia, h = sensor_pcb_h + 2);
+    }
+    
+    color("#303030")
+    translate([-sensor_chip_w / 2, -sensor_l / 2 - sensor_chip_l + sensor_edge_to_pin1 + sensor_cut_off_y + sensor_cut_h - sensor_cut_edge_to_pin1, -sensor_chip_h])
+    cube([sensor_chip_w, sensor_chip_l, sensor_chip_h]);
+    
+    translate([0, -sensor_l / 2 - 15 * sensor_pin_pitch + sensor_cut_off_y + sensor_cut_h - sensor_cut_edge_to_pin1, 0])
+    for (p = [0 : 15])
+    translate([0, p * sensor_pin_pitch, 0])
+    for (x = [-sensor_pin_dist / 2, sensor_pin_dist / 2])
+    if (((p % 2 == 0) && (x < 0))
+            || ((p % 2 == 1) && (x > 0)))
+    translate([-sensor_pin_d / 2 + x, -sensor_pin_w / 2, -sensor_chip_h + sensor_pin_off_top])
+    cube([sensor_pin_d, sensor_pin_w, sensor_pin_h]);
+    
+    color("cyan")
+    translate([0, -sensor_l / 2 + sensor_cut_off_y + sensor_cut_h - sensor_cut_edge_to_pin1 - sensor_pin1_to_optical_center, -sensor_chip_h + 1])
+    cylinder(d = 0.2, h = sensor_ball_to_chip_bottom - 1);
+}
+
+module ball_and_roller() {
+    color("red")
+    sphere(d = ball_dia, $fn = 200);
+    
+    for (r = [0 : roller_count - 1])
+    rotate([0, 0, roller_mount_angle_off + 360 / roller_count * r])
+    translate([sphere_r_at_h(roller_ball_h - ball_dia / 2, ball_dia / 2), 0, -ball_dia / 2 + roller_ball_h])
+    rotate([0, 180 + sphere_angle_at_rh(roller_ball_h - ball_dia / 2, ball_dia / 2), 0])
+    translate([0, 0, -roller_dia / 2])
+    roller_holder();
+}
+
+module roller_holder() {
+    translate([0, 0, -roller_h + roller_dia / 2 - roller_ball_h_off])
+    difference() {
+        color("magenta")
+        union() {
+            translate([0, 0, roller_h - roller_ridge_h])
+            cylinder(d = roller_mount_dia, h = roller_ridge_h, $fn = 6);
+            
+            translate([0, 0, roller_h - roller_ridge_h])
+            scale([1, 1, -1])
+            metric_thread(diameter = roller_thread_dia,
+                    pitch = roller_thread_pitch,
+                    length = roller_h - roller_ridge_h,
+                    internal = false, n_starts = 1,
+                    taper = 0.1, leadin = 2,
+                    test = !draw_threads);
+        }
+        
+        translate([0, 0, -1]) {
+            cylinder(d = roller_thread_hole, h = roller_h + 1 - roller_dia / 2 + roller_ball_h_off + roller_ball_hold_off);
+            
+            cylinder(d = roller_small_hole, h = roller_h + 2);
+        }
+        
+        if (cut_roller_holder) {
+            translate([-roller_thread_dia / 2 - 1, -roller_thread_dia, -1])
+            cube([roller_thread_dia + 2, roller_thread_dia, roller_h + 2]);
+        }
+    }
+    
+    %color("blue")
+    sphere(d = roller_dia);
+}
+
+module roller_mount() {
+    difference() {
+        color("cyan")
+        cylinder(d = roller_mount_dia, h = roller_h - roller_ridge_h);
+        
+        translate([0, 0, roller_h - roller_ridge_h])
+        scale([1, 1, -1])
+        metric_thread(diameter = roller_thread_dia,
+                pitch = roller_thread_pitch,
+                length = roller_h - roller_ridge_h,
+                internal = true, n_starts = 1,
+                taper = 0, leadin = 2,
+                test = !draw_threads);
+        
+        if (cut_roller_holder) {
+            translate([-roller_thread_dia / 2 - 2, -roller_thread_dia, -1])
+            cube([roller_thread_dia + 4, roller_thread_dia, roller_h + 2]);
+        }
+    }
+}
+
+module roller_mount_test() {
+    roller_mount();
+    
+    translate([0, 0, roller_h - roller_dia / 2 + roller_ball_h_off])
+    roller_holder();
+}
+
+base_dia = pico_l + 9;
+
+module trackball() {
+    %translate([0, 0, ball_dia / 2 + ball_h])
+    ball_and_roller();
+    
+    %rotate([0, 180, 0])
+    pico();
+    
+    %translate([0, sensor_l / 2 - sensor_cut_off_y - sensor_cut_h + sensor_cut_edge_to_pin1 + sensor_pin1_to_optical_center, ball_h + sensor_chip_h - sensor_ball_to_chip_bottom])
+    sensor();
+    
+    translate([0, 0, ball_dia / 2 + ball_h])
+    for (r = [0 : roller_count - 1])
+    rotate([0, 0, roller_mount_angle_off + 360 / roller_count * r])
+    translate([sphere_r_at_h(roller_ball_h - ball_dia / 2, ball_dia / 2), 0, -ball_dia / 2 + roller_ball_h])
+    rotate([0, 180 + sphere_angle_at_rh(roller_ball_h - ball_dia / 2, ball_dia / 2), 0])
+    translate([0, 0, -roller_dia / 2])
+    translate([0, 0, -roller_h + roller_dia / 2 - roller_ball_h_off])
+    roller_mount();
+    
+    color("grey")
+    translate([0, 0, -8])
+    cylinder(d = base_dia, h = wall);
+}
+
+// ######################
+// ## Rendering Select ##
+// ######################
+
+//ball_and_roller();
+//pico();
+//sensor();
+//mx_switch_cutout(wall);
+//mx_switch_test();
+//roller_mount_test();
+
+//roller_holder();
+trackball();